MySQL :: X DevAPI 使用者指南 :: 11.7 其他 EBNF 定義

X DevAPI 使用者指南 / CRUD EBNF 定義 / 其他 EBNF 定義

11.7 其他 EBNF 定義

SearchConditionStr

此函數在 EBNF 中顯示的語法為

SearchConditionStr
  ::= '"' Expression '"'

圖 11.24 SearchConditionStr

SearchExprStrList

此函數在 EBNF 中顯示的語法為

SearchExprStrList
  ::= '[' '"' Expression '"' ( ',' '"' Expression '"' )* ']'

圖 11.25 SearchExprStrList

Image shows the syntax in EBNF form as described in the preceding text.

ProjectedDocumentExprStr

此函數在 EBNF 中顯示的語法為

ProjectedDocumentExprStr
  ::= ProjectedSearchExprStrList | 'expr("' JSONDocumentExpression '")'

圖 11.26 ProjectedDocumentExprStr

ProjectedSearchExprStrList

此函數在 EBNF 中顯示的語法為

ProjectedSearchExprStrList
  ::= '[' '"' Expression ( 'AS' Alias )? '"' ( ',' '"' Expression ( 'AS' Alias )? '"' )* ']'

圖 11.27 ProjectedSearchExprStrList

SortExprStrList

此函數在 EBNF 中顯示的語法為

SortExprStrList
  ::= '[' '"' Expression ( 'ASC' | 'DESC' )? '"' ( ',' '"' Expression ( 'ASC' | 'DESC' )? '"' )* ']'

圖 11.28 SortExprStrList

ExprOrLiteral

此函數在 EBNF 中顯示的語法為

ExprOrLiteral
  ::= 'expr("' Expression '")' | Literal

圖 11.29 ExprOrLiteral

ExprOrLiterals

此函數在 EBNF 中顯示的語法為

ExprOrLiterals
  ::= ExprOrLiteral ( ',' ExprOrLiteral )*

圖 11.30 ExprOrLiterals

ExprOrLiteralOrOperand

此函數在 EBNF 中顯示的語法為

ExprOrLiteralOrOperand
  ::= ExprOrLiteral

圖 11.31 ExprOrLiteralOrOperand

PlaceholderValues

此函數在 EBNF 中顯示的語法為

PlaceholderValues
  ::= '{' PlaceholderName ':' ( ExprOrLiteral ) '}'

圖 11.32 PlaceholderValues

PlaceholderName

此函數在 EBNF 中顯示的語法為

PlaceholderName
  ::= NamedPlaceholderNotQuestionmarkNotNumbered

圖 11.33 PlaceholderName

DocPath

此函數在 EBNF 中顯示的語法為

DocPath
  ::= ( '[*]' | ( '[' Index ']' ) | '.*' | ( '.' StringLiteral ) | '**' )+

圖 11.34 DocPath

Literal

此函數在 EBNF 中顯示的語法為

Literal
  ::= '"' StringLiteral '"' | Number | true | false | Document

圖 11.35 Literal

Expression

Expression
  ::= Literal
   | DocPath
   | TableField
   | FunctionName '(' Expression ( ',' Expression )* ')'
   | ':' PlaceholderName
   | Expression Operator Expression
   | JSONExpression

圖 11.36 Expression

Document

預期 JSON 文件的 API 呼叫允許使用許多資料類型來描述文件。根據 X DevAPI 的實作和語言，可以使用下列任何資料類型

字串
原生 JSON
JSON 等效語法
DbDoc
產生的文件類別

X DevAPI 的所有實作都允許以特殊 DbDoc 類型和字串來表示文件。

此函數在 EBNF 中顯示的語法為

Document
  ::= JSONDocument | JSONEquivalentDocument | DbDoc | GeneratedDocumentClasses

圖 11.37 Document

JSONExpression

此函數在 EBNF 中顯示的語法為

JSONExpression
  ::= JSONDocumentExpression | '[' Expression ( ',' Expression )* ']'

圖 11.38 JSONExpression

JSONDocumentExpression

此函數在 EBNF 中顯示的語法為

JSONDocumentExpression
  ::= '{' StringLiteral ':' JSONExpression (',' StringLiteral ':' JSONExpression)* '}'

圖 11.39 JSONDocumentExpression

FunctionName

此函數在 EBNF 中顯示的語法為

FunctionName
  ::= StringLiteral | StringLiteral '.' StringLiteral

圖 11.40 FunctionName

DocumentOrJSON

此函數在 EBNF 中顯示的語法為

DocumentOrJSON
  ::= Document | 'expr("' JSONDocumentExpression '")'

圖 11.41 DocumentOrJSON

TableField

此函數在 EBNF 中顯示的語法為

TableField
  ::= ( StringLiteral '.' )? ( StringLiteral '.' )? StringLiteral ( '@' DocPath )?

圖 11.42 TableField

TableFields

此函數在 EBNF 中顯示的語法為

TableFields
  ::= ( '[' TableField ( ',' TableField )* ']' )

圖 11.43 TableFields