此函數的語法以 EBNF 顯示如下

SearchConditionStr
  ::= '"' Expression '"'

圖 11.24 SearchConditionStr

此函數的語法以 EBNF 顯示如下

SearchExprStrList
  ::= '[' '"' Expression '"' ( ',' '"' Expression '"' )* ']'

圖 11.25 SearchExprStrList

此函數的語法以 EBNF 顯示如下

ProjectedDocumentExprStr
  ::= ProjectedSearchExprStrList | 'expr("' JSONDocumentExpression '")'

圖 11.26 ProjectedDocumentExprStr

此函數的語法以 EBNF 顯示如下

ProjectedSearchExprStrList
  ::= '[' '"' Expression ( 'AS' Alias )? '"' ( ',' '"' Expression ( 'AS' Alias )? '"' )* ']'

圖 11.27 ProjectedSearchExprStrList

此函數的語法以 EBNF 顯示如下

SortExprStrList
  ::= '[' '"' Expression ( 'ASC' | 'DESC' )? '"' ( ',' '"' Expression ( 'ASC' | 'DESC' )? '"' )* ']'

圖 11.28 SortExprStrList

此函數的語法以 EBNF 顯示如下

ExprOrLiteral
  ::= 'expr("' Expression '")' | Literal

圖 11.29 ExprOrLiteral

此函數的語法以 EBNF 顯示如下

ExprOrLiterals
  ::= ExprOrLiteral ( ',' ExprOrLiteral )*

圖 11.30 ExprOrLiterals

此函數的語法以 EBNF 顯示如下

ExprOrLiteralOrOperand
  ::= ExprOrLiteral

圖 11.31 ExprOrLiteralOrOperand

此函數的語法以 EBNF 顯示如下

PlaceholderValues
  ::= '{' PlaceholderName ':' ( ExprOrLiteral ) '}'

圖 11.32 PlaceholderValues

此函數的語法以 EBNF 顯示如下

PlaceholderName
  ::= NamedPlaceholderNotQuestionmarkNotNumbered

圖 11.33 PlaceholderName

此函數的語法以 EBNF 顯示如下

DocPath
  ::= ( '[*]' | ( '[' Index ']' ) | '.*' | ( '.' StringLiteral ) | '**' )+

圖 11.34 DocPath

此函數的語法以 EBNF 顯示如下

Literal
  ::= '"' StringLiteral '"' | Number | true | false | Document

圖 11.35 Literal

Expression
  ::= Literal
   | DocPath
   | TableField
   | FunctionName '(' Expression ( ',' Expression )* ')'
   | ':' PlaceholderName
   | Expression Operator Expression
   | JSONExpression

圖 11.36 Expression

預期 JSON 文件的 API 呼叫允許使用許多資料類型來描述文件。根據 X DevAPI 實作和語言，可以使用以下任何資料類型

所有 X DevAPI 實作都允許以特殊的 DbDoc 類型和字串來表示文件。

此函數的語法以 EBNF 顯示如下

Document
  ::= JSONDocument | JSONEquivalentDocument | DbDoc | GeneratedDocumentClasses

圖 11.37 Document

此函數的語法以 EBNF 顯示如下

JSONExpression
  ::= JSONDocumentExpression | '[' Expression ( ',' Expression )* ']'

圖 11.38 JSONExpression

此函數的語法以 EBNF 顯示如下

JSONDocumentExpression
  ::= '{' StringLiteral ':' JSONExpression (',' StringLiteral ':' JSONExpression)* '}'

圖 11.39 JSONDocumentExpression

此函數的語法以 EBNF 顯示如下

FunctionName
  ::= StringLiteral | StringLiteral '.' StringLiteral

圖 11.40 FunctionName

此函數的語法以 EBNF 顯示如下

DocumentOrJSON
  ::= Document | 'expr("' JSONDocumentExpression '")'

圖 11.41 DocumentOrJSON

此函數的語法以 EBNF 顯示如下

TableField
  ::= ( StringLiteral '.' )? ( StringLiteral '.' )? StringLiteral ( '@' DocPath )?

圖 11.42 TableField

此函數的語法以 EBNF 顯示如下

TableFields
  ::= ( '[' TableField ( ',' TableField )* ']' )

圖 11.43 TableFields